;original MEMO.CMD copyright (c)  1989
;    by Paul Globman

; new tweaked version by T. Sosnow. 2023
;
	ORG 65362	;telcom buffer
			;TS: This is buffer that holds the Alarm text on the bottom of the screen
			;For some reason it's huge like 80bytes

; CO header here:
	DW 65362
	DW END-65362
	DW 65362
	
;MEMO SOURCE
;

;	ENTRY
;
;LOADM XBASIC IN M/L....
;
	CALL 41179	;load XBAS-2
	MVI A,8		;LOADM command
	LXI H,XB	;VARPTR(X$)
	CALL 63600	;execute
	LDA 61302	;look at RD
	ANA A		;test A for 0
	JNZ 32D2H	;beep and MENU

; new error handler to make HOTKEY.BA work
	LXI H, 06860H
	SHLD 0EF34H
; will be restored if exited thru 6860H
;
;GET MEMO INPUT
;
MM:	CALL 04F72H	;erase btm line
	CALL 054F6H	;GET MEMO
	JC 06860H	;abort if break
	MOV A,B
	DCR A		;test length
	JZ 06860H	;abrt if null
	STA DATA	;STORE LEN
;
;OPEN 2:MEMO.DO
;
	MVI A,2		;OPEN WRITE CMD
	LXI H,MEMO
	CALL 63600	;DO THE OPEN
;
;WRITE DATA
;
	MVI A,4		;WRITE CMD
	LXI H,DATA
	CALL 63600	;DO THE WRITE
;
;WRITE CRLF
;
	MVI A,4		;WRITE CMD
	LXI H,CRLF
	CALL 63600	;DO THE WRITE
;
;CLOSE MEMO
;
	XRA A		;CLOSE CMD
	CALL 63600
;
;NEXT MEMO
;
	JMP MM		;LOOP
;
;
XB:	DB 11		;VARPTR(X$)
	DW XB+3		;POINTER
	DB '3:XBASIC.CO'	;X$
;
MEMO:	DB 6		;VARPTR(MEMO$)
	DW MEMO+3
	DB '2:MEMO'	;MEMO$
;
DATA:	DB 0		;VARPTR(DATA$)
	DW 0EF70H	;INPUT BUFFER
;
CRLF:	DB 2		;VARPTR(CRLF$)
	DW 0423H	;CRLF from BASIC "Ok" string
;	DW CRLF+3
;	DB 13,10	;CRLF$
END